site Metamodel
    description:
        Documenting the Dbquity Metamodel as a site model :-)
        Because many keywords in the Dbquity language are overloaded in this model,
        it is suitable for documentation purposes only.

    class expression
        text body
            multiline
    expression behaviour
    expression execution
    class semanticversion
        modelurl: "https://semver.org"
        description: <major>[.<minor>[.patch]][-<prerelease>][+build]
        integer major
        integer minor
        integer patch
        text prerelease
        text build
        constraint: major >= 0 and (not patch or minor) and not (minor < 0 or patch < 0)
        text promotion
            expression: major|(if minor then '.'|minor)|(if patch then '.'|patch)|
                        (if prerelease then '-'|prerelease)|(if build then '+'|build)

    area Core
        association element_declares_elements
            abstract
            end owner
                owning
                entity: element
                multiplicity: 1
            end element
            diagramhint: label="" taillabel=""
        association model_declares_classifiers
            end classifier
            end model
                multiplicity: 0..1
                owning
            diagramhint: label="" arrowhead="diamond"
        association complex_declares_classifiers
            end classifier
            end complex
                multiplicity: 0..1
                owning
            diagramhint: label="" arrowhead="diamond"
        entity element            
            stereotype
            text name
            identity: name
            link owner
                entity: element
                expression: element@element_declares_elements.single().owner
                diagramhint: style="invis"
            text fullname
                expression: (if owner then owner.fullname|"\\")|name
        element classifier
            collection: classifiers
            modelurl: if not (identity in "classifier";"complex") then identity|".html"
            stereotype
        classifier complex
            stereotype
            boolean abstract
                default: (not owner) or members.any(abstract)
            boolean sealed
            element member
                stereotype
                collection: members
                modelurl: if identity <> "member" then identity|".html"
                owner -> owner
                    entity: complex
                boolean abstract
            element property
                collection: properties
                description:
                    property <name>
                        type: <primitive>|<class-name>|<enumeration-name>
                        constraint: <expression>    # evaluated when parsed by the CLI
                modelurl: identity|".html"
                diagramhint: label=<«element»<br/>property>
        element model
            modelurl: if identity <> "model" then identity|".html"
            stereotype
            text origin
            semanticversion version
            text unversionedname
                expression: origin|":"|name
            text fullname
                expression: unversionedname|":"|version.promotion
            identity: fullname
            link references
                list
                entity: model
                diagramhint: headport=s tailport=s headlabel=<> label=<references   >

    area Delta
        class change
            text target
            text before
                multiline
            text after
                multiline
        model patch
            collection: pathces
            element modification
                collection: modifications
                link target
                    entity: element
        association modification_carries_elements
            end modification
                multiplicity: 0..1
                owning
            end element
            diagramhint: label="«carries»"
                
    enumeration primitives
        description:
            The built-in, primitive data types for fields of class and entity models
        modelurl: "primitives.html"
        options: text|boolean|character|integer|decimal|real|date|datetime|time|guid
        
    area Models
        model site
            collection: sites
            description:
                site <name>
                    origin: <webfolder>
                    version: <semantic-version>
                    references: <list-of-model-references>
                    class <name>
                        ...
                    enumeration <name>
                        ...
                    entity <name>
                        ...
                    area <name>
                        entity <name>
                            ...
                        association <name>
                            ...
                        ...
                    area <name>
                        ...
                    ...
            diagramhint: nobaselink
            text adminprofile
        model library
            collection: libraries
            description:
                library <name>
                    origin: <webfolder>
                    version: <semantic-version>
                    references: <list-of-model-references>
                    class <name>
                        ...
                    enumeration <name>
                        ...
                    entity <name>
                        ...
                    association <name>
                        ...
                    ...
            diagramhint: nobaselink

    area Members
        member field
            stereotype
            modelurl: identity|".html"
        member action
            diagramhint: nobaselink
        member function
            description:
                function <name>
                    parameter <name>
                    parameter <name>
                        ...
                    guard: <expression>
                    expression: <expression
            diagramhint: nobaselink
            element parameter
                collection: parameters
                description:
                    parameter <name>
                        constraint: <expression>
                        scope: <expression>
                modelurl: "function.html"
                diagramhint: nobaselink
        field primitive
            abstract
            description:
                <primitive> <name>
                    constraint: <expression>
                    expression: <expression>
                    default: <expression>
                    initialization: <expression>
                    readonly[: <expression>]
                    hidden[: <expression>]
                    ...
        field enumeration
            modelurl: "enumeration-field.html"
            link enumeration
                entity: Classifiers\enumeration
            description:
                <enumeration-name> <name>
                    constraint: <expression>
                    expression: <expression>
                    default: <expression>
                    initialization: <expression>
                    readonly[: <expression>]
                    hidden[: <expression>]
                    ...
        field class
            modelurl: "class-field.html"
            link class
                entity: Classifiers\class
            description:
                <class-name> <name>
                    constraint: <expression>
                    expression: <expression>
                    default: <expression>
                    initialization: <expression>
                    readonly[: <expression>]
                    hidden[: <expression>]
                    ...
        field link_
            modelurl: "link.html"
            link entity
                entity: Classifiers\entity
            description:
                link <name>
                    entity: <entity-name>
                    constraint: <expression>
                    expression: <expression>
                    default: <expression>
                    initialization: <expression>
                    readonly[: <expression>]
                    hidden[: <expression>]
                    ...
            diagramhint:label=<«field»<br/>link>
    area Classifiers
        classifier enumeration
            description:
                enumeration <name>
                    options: <option1>|<option2>|...|<optionN>
            diagramhint: nobaselink
            text options
                multiline
        complex class
            description:
                class <name>
                    description: ...
                    modelconstraint: <expression>   # evaluated when parsed by the CLI
                                                    # and (often) refers property values
                    constraint: <expression>        # evaluated at runtime
                    <primitive>|<class-name>|<enumeration-name> <name>
                    ...
            diagramhint: nobaselink
        complex entity
            description:
                entity <name>
                    description: ...
                    modelconstraint: <expression>   # evaluated when parsed by the CLI
                                                    # and (often) refers property values
                    constraint: <expression>        # evaluated at runtime
                    <primitive>|<class-name>|<enumeration-name> <name>
                    identity: <field-name>
                    ...
            member filter
                collection: filters
                diagramhint: nobaselink
            member query
                collection: queries
                diagramhint: shape="diamond" style="rounded" nobaselink
            member step
                collection: behaviour
                diagramhint: nobaselink
        entity association
            description:
                association <name>
                    end <entity-name>
                        [multiplicity: 0..1|1|*|1..*|l..u]
                    end <other-entity-name>
                        [multiplicity: 0..1|1|*|1..*|l..u]
                    <primitive>|<class-name>|<enumeration-name> <name>
                    ...
            link_ end
                collection: ends
                owner -> owner
                    entity: Classifiers\association
                description:
                    end <name>
                        entity: <entity-name>
                        multiplicity: 0..1|1|*|1..*|l..u
                        constraint: <expression>
                        expression: <expression>
                        default: <expression>
                        initialization: <expression>
                        readonly[: <expression>]
                        hidden[: <expression>]
                        scope: <expression>
                        ...
                modelurl: identity|".html"
                diagramhint:label=<«field»<br/>end>
        entity container
            description:
                container <name>
                    <primitive>|<class-name>|<enumeration-name> <name>
                    entity <name>
                        ...
                    entity <name>
                        ...
                    permissions: <permission-expr>
                    ...
        container area
            description:
                area <name>
                    <primitive>|<class-name>|<enumeration-name> <name>
                    entity <name>
                        ...
                    entity <name>
                        ...
                    permissions: <permission-expr>
                    ...
        entity blob
            description:
                blob <name>
                    <primitive>|<class-name>|<enumeration-name> <name>
                    ...